Dans ce tutoriel je vous montre pas-à-pas comment mettre en place dans vos tableaux de board Power BI une sélection de dates aux petits oignons 🧅

Toutes les options s’offrent aux utilisateurs :

Des configurations dynamiques comme MTD

Des configuration statiques comme Vague 1 (avec date de début et de fin fixes)

Des configuration personnalisées grâce à l’option Custom + la sélection de la plage de date

Ce genre de demande pour les sélections de dates ultra flexibles, c’est quelque chose qui revient en permanence lorsque l’on créé des dashboards (peu importe l’outil). D’ailleurs c’est des choses que j’ai l’habitude de faire sur Tableau. 💡

Quand j’ai voulu répliquer le même système sur Power BI, je me suis heurtée à quelques difficultés : avoir toutes les options au même endroit, eh bah, c’était pas si facile ! ⛰️

Mais à force de tests, j’ai mis au point une méthode qui fonctionne et que j’aimerai bien simplifier dans le futur ! 🚀

Pour vous faciliter la vie, je vais passer en revue dans ce tutoriel toutes les étapes pour construire ce sélecteur de A à Z.

S’il y a des points que vous voulez sauter, n’hésitez pas à utiliser cette table des matières ⬇️

1. Les tables à créer 1.1. La création des tables A. Les calendriers B. Les périodes 1.2. Les relations entre les tables A. Calendar <> Table de métriques B. Calendar Comparison <> Table de métriques C. Calendar <> Date Period D. Modèle global 2. La mise en place des slicers 2.1. Les éléments 2.2. Les mesures de filtre 2.3. Les interactions entre les visuels 3. Les mesures 3.1. Les dates de début et de fin de période 3.2. La période principale 3.3. La période de comparaison 3.4. [Bonus] Les % de différence

`1.` Les tables à créer

`1.1.` La création des tables

`A.` Les calendriers

Pour ceux qui ont déjà joué avec les dates dans Power BI, vous savez déjà qu’il faut créer une table de calendrier pour que tout ce petit monde fonctionne correctement, pour les autres c’est très simple :

On va dans l’onglet Accueil > Nouvelle Table > et on entre cette mesure ⬇️

sql
Calendar = 
CALENDAR(
    MIN('Table'[date]),
    MAX('Table'[date])
)

Ça donnera tous les jours (donc sans trou, même si vous en avez dans la table de base) entre la date min et max.

'Table'[date] est le champ de date de la table où il y a vos mesures. S’il vous avez plusieurs tables avec des mesures, prenez le champ de date dans la table où il est le plus étendu.

🧚‍♀️ La dernière étape pour parfaire cette étape est de marquer notre table Calendar en tant que table de date (on peut faire ça dans le modèle > … > Marquer comme table de dates

À quoi ça sert ?

C’est un filet de sécurité dans le cas où les colonnes de dates ne sont pas de type date mais integer pour éviter d’ajouter des REMOVEFILTERS() partout (car Power BI le fait implicitement quand une relation est basée sur des dates).

La table Calendar sera utilisée en tant que table date principale. Mais on aura aussi besoin d’une table de date secondaire (Accueil > Nouvelle Table) :

sql
Calendar Comparison = 'Calendar'

Calendar Comparison est un replica de Calendar

`B.` Les périodes

Maintenant que nous avons nos deux calendriers, il nous faut des tables avec nos différentes options de sélection de période :

Pour la période principale

Configurations dynamiques

MTD

sql
DATESMTD('Calendar'[Date])

Formule DAX permettant d’avoir les dates du mois en cours jusqu’à aujourd’hui

QTD

sql
DATESQTD('Calendar'[Date])

Formule DAX permettant d’avoir les dates du trimestre en cours jusqu’à aujourd’hui

YTD

sql
DATESYTD('Calendar'[Date])

Formule DAX permettant d’avoir les dates de l’année en cours jusqu’à aujourd’hui

Last Month

sql
PREVIOUSMONTH(DATESMTD('Calendar'[Date]))

Formule DAX permettant d’avoir les dates du mois dernier

Last Quarter

sql
PREVIOUSQUARTER(DATESQTD('Calendar'[Date]))

Formule DAX permettant d’avoir les dates du trimestre dernier

Last Year

sql
PREVIOUSYEAR(DATESYTD('Calendar'[Date]))

Formule DAX permettant d’avoir les dates de l’année dernière

All Time

sql
CALENDAR(MIN('Calendar'[Date]), MAX('Calendar'[Date]))

Formule DAX permettant d’avoir toutes les dates

Configuration statique

Vague 1

sql
CALENDAR("2024-04-04", "2024-04-30")

Formule DAX permettant d’avoir les jours entre deux dates (Remplacez 2024-04-04 et 2024-04-30 avec la date de début et de fin souhaitée)

Configuration personnalisée

Custom

Pour la période de comparaison

Previous Period

Qui doit, quand des configurations dynamiques sont sélectionnées dans la période principale, prendre la valeur de Previous MTD (par exemple) et pas simplement le même nombre de jours juste avant.

Same Period Last Year

Custom

Je vous propose toutes ces options mais bien évidemment, ne gardez que celles qui sont pertinentes à votre use case.

Pour la période principale, on utilise les formules de time intelligence proposées directement par Power BI (je les ai détaillées dans les toggles plus haut).

Avec ça, on créé une nouvelle table (Accueil > Nouvelle Table) qui décrit toutes nos périodes :

Date Period

sql
Date Period = 
UNION(
    ADDCOLUMNS(
        DATESMTD('Calendar'[Date]),
        "Type", "MTD",
        "Order", 1
    ),
    ADDCOLUMNS(
        DATESQTD('Calendar'[Date]),
        "Type", "QTD",
        "Order", 2
    ),
    ADDCOLUMNS(
        DATESYTD('Calendar'[Date]),
        "Type", "YTD",
        "Order", 3
    ),
    ADDCOLUMNS(
        PREVIOUSMONTH(DATESMTD('Calendar'[Date])),
        "Type", "Last Month",
        "Order", 4
    ),
    ADDCOLUMNS(
        PREVIOUSQUARTER(DATESQTD('Calendar'[Date])),
        "Type", "Last Quarter",
        "Order", 5
    ),
    ADDCOLUMNS(
        PREVIOUSYEAR(DATESYTD('Calendar'[Date])),
        "Type", "Last Year",
        "Order", 6
    ),
    ADDCOLUMNS(
        CALENDAR(MIN('Calendar'[Date]), MAX('Calendar'[Date])),
        "Type", "All Time",
        "Order", 7
    ),
    ADDCOLUMNS(
        CALENDAR("2024-04-04", "2024-04-30"),
        "Type", "Vague 1",
        "Order", 8
    ),
    ADDCOLUMNS(
        CALENDAR(MIN('Calendar'[Date]), MAX('Calendar'[Date])),
        "Type", "Custom",
        "Order", 9
    )
)

La colonne Order est là pour l’utiliser en champ de tri sur la colonne Type.

Pour la période de comparaison, on n’utilise pas les formules de time intelligence parce que les options doivent être capables de s’adapter à la sélection de la période principale. On créé donc une table toute simple :

Date Period Comparison

sql
Date Period Comparison = 
DATATABLE(
    "comparison period", STRING,
    "Order", INTEGER,
    {
        {"Previous Period", 1},
        {"Same Period Last Year", 2},
        {"Vague 1", 3},
        {"Custom", 4}
    }
)

Encore une fois, la colonne Order est là pour l’utiliser en champ de tri sur la colonne comparison period.

`1.2.` Les relations entre les tables

C’est la où la première étape se joue vraiment !

Il faut bien configurer les relations entre nos tables

`A.` `Calendar` <> `Table de métriques`

Entre Date et measured_at (le champ de date de ma table de métriques) il faut une relation 1:* à sens unique (de Calendar à Table de métriques). Chaque ligne de la table de métriques se relie à une seule ligne du calendrier, mais chaque ligne du calendrier peut être utilisée plusieurs fois.

Laissez cette relation active ⬇️

Les relations actives filtrent directement les autres tables sans action supplémentaire de notre part tandis que les relations inactives ont besoin d’une précision dans une expression DAX (USERELATIONSHIP()) pour filtrer quelque chose.

`B.` `Calendar Comparison` <> `Table de métriques`

Entre Date et measured_at (le champ de date de ma table de métriques) il faut une relation 1:* à sens unique (de Calendar Comparison à Table de métriques). Chaque ligne de la table de métriques se relie à une seule ligne du calendrier de comparaison, mais chaque ligne du calendrier de comparaison peut être utilisée plusieurs fois.

Rendre la relation inactive ⬇️

`C.` `Calendar` <> `Date Period`

Entre Date et Date il faut une relation 1:* à double sens (de Calendar à Date Period)

`D.` Modèle global

Et voilà ! 🎉 Notre modèle est fin prêt ! Passons à la mise en place du visuel.

Note : Il n’y a pas de relation entre Date Period Comparison et d’autres tables. — Note : Il n’y a pas de relation entre `Date Period Comparison` et d’autres tables.

`2.` La mise en place des slicers

`2.1.` Les éléments

Pour créer l’élément de gestion des périodes il vous faudra 4 segments différents :

Un segment pour mettre les option de dates de la période principale (Date Period.Type)

Un segment pour mettre le date range de la période principale si l’utilisateur choisit de sélectionner une période customisée (Calendar.Date)

Un segment pour mettre les option de dates de la période principale (Date Period Comparison.comparison period)

Un segment pour mettre le date range de la période de comparaison si l’utilisateur choisit de sélectionner une période customisée (Calendar Comparison.Date)

`2.2.` Les mesures de filtre

Pour ne pas que les utilisateurs soient confus, il faut que les deux segments de date range soient désactivés (donc inutilisables) lorsque l’option Custom liée n’est pas sélectionnée.

Pour ça, il faut créer une mesure pour chaque date range qui servira de filtre pour que l’élément soit seulement actif quand Custom est choisit :

sql
Date Range Filter = 
IF(
    SELECTEDVALUE('Date Period'[Type]) = "Custom",
    1,
    0
)

Pour la période principale

sql
Date Range Filter Comparison = 
IF(
    SELECTEDVALUE('Date Period Comparison'[comparison period]) = "Custom",
    1,
    0
)

Pour la période de comparaison

Pour les composants 2 et 4, il faut respectivement amener Date Range Filter et Date Range Filter Comparison dans le panel des filtres et mettre la condition est 1.

`2.3.` Les interactions entre les visuels

Le set-up est presque terminé ! Il ne manque plus qu’à éditer les interactions pour que les deux segments responsables du type de période agissent sur son date range respectif, mais pour que le date range n’agissent pas sur le type de période (i.e. on ne veut pas que si notre dernière sélection customisée est les 7 derniers jours, ne plus être capable de sélectionner Last Month dans le dropdown).

Pour ça, sélectionner un visuel > Format > Modifier les interactions.

`3.` Les mesures

Voilà (enfin) l’étape où notre sélection de période va nous servir ! 🎉

`3.1.` Les dates de début et de fin de période

Pour certaines mesures, on aura besoin d’avoir les dates de début et de fin de période. Voilà comment les calculer.

Période principale (pré-requis à la période de comparaison)

sql
Current Period Start Date =
-- for all the other date period options than the date range (e.g. MTD) we want to ignore the selection in the date slicer
SWITCH (
    TRUE (),
    SELECTEDVALUE ( 'Date Period'[Type] ) = "Custom", FIRSTDATE ( 'Calendar'[Date] ),
    CALCULATE ( FIRSTDATE ( 'Calendar'[Date] ), REMOVEFILTERS ( 'Calendar'[Date] ) )
)

REMOVEFILTERS ( 'Calendar'[Date] ) est indispensable pour que la sélection dans le date range n’impacte pas la future sélection dans le dropdown du type de période.

sql
Current Period End Date =
-- for all the other date period options than the date range (e.g. MTD) we want to ignore the selection in the date slicer
SWITCH (
    TRUE (),
    SELECTEDVALUE ( 'Date Period'[Type] ) = "Custom", LASTDATE ( 'Calendar'[Date] ),
    CALCULATE ( LASTDATE ( 'Calendar'[Date] ), REMOVEFILTERS ( 'Calendar'[Date] ) )
)

sql
Current Period Number Of Days =
-- for all the other date period options other than the date range (e.g. MTD) we want to ignore the selection in the date slicer
SWITCH (
    TRUE (),
    SELECTEDVALUE ( 'Date Period'[Type] ) = "Custom", DATEDIFF ( [Current Period Start Date], [Current Period End Date], DAY ),
    CALCULATE (
        DATEDIFF ( [Current Period Start Date], [Current Period End Date], DAY ),
        REMOVEFILTERS ( 'Calendar'[Date] )
    )
)

Période de comparaison

sql
Full Comparison Period Start Date =
SWITCH (
    SELECTEDVALUE ( 'Date Period Comparison'[comparison period] ),
    "Custom",
        MINX (
            CALCULATETABLE (
                VALUES ( 'Calendar Comparison'[Date] ),
                USERELATIONSHIP ( 'Calendar Comparison'[Date], TableDeMetrique[measured_at] ),
                ALL ( 'Calendar' )
            ),
            'Calendar Comparison'[Date]
        ),
    "Previous Period",
        SWITCH (
            SELECTEDVALUE ( 'Date Period'[Type] ),
            // MTD : Calcul du même jour du mois précédent
            "MTD", EDATE ( MIN ( 'Calendar'[Date] ), -1 ),
            // QTD : Calcul du même jour du trimestre précédent
            "QTD", EDATE ( MIN ( 'Calendar'[Date] ), -3 ),
            // YTD : Calcul du même jour de l'année précédente
            "YTD",
                DATE ( YEAR ( MIN ( 'Calendar'[Date] ) ) - 1, MONTH ( MIN ( 'Calendar'[Date] ) ), DAY ( MIN ( 'Calendar'[Date] ) ) ),
            [Current Period Start Date] - [Current Period Number Of Days]
        ),
    "Same Period Last Year",
        DATE ( YEAR ( MIN ( 'Calendar'[Date] ) ) - 1, MONTH ( MIN ( 'Calendar'[Date] ) ), DAY ( MIN ( 'Calendar'[Date] ) ) ),
    "Vague 1", DATE ( 2024, 4, 4 ),
    BLANK ()
)

EDATE() sert à retourner la date du nombre de mois indiqué en deuxième paramètre

sql
Full Comparison Period End Date =
SWITCH (
    SELECTEDVALUE ( 'Date Period Comparison'[comparison period] ),
    "Custom",
        MAXX (
            CALCULATETABLE (
                VALUES ( 'Calendar Comparison'[Date] ),
                USERELATIONSHIP ( 'Calendar Comparison'[Date], TableDeMetrique[measured_at] ),
                ALL ( 'Calendar' )
            ),
            'Calendar Comparison'[Date]
        ),
    "Previous Period",
        SWITCH (
            SELECTEDVALUE ( 'Date Period'[Type] ),
            // MTD : Calcul du même jour du mois précédent
            "MTD", EDATE ( MAX ( 'Calendar'[Date] ), -1 ),
            // QTD : Calcul du même jour du trimestre précédent
            "QTD", EDATE ( MAX ( 'Calendar'[Date] ), -3 ),
            // YTD : Calcul du même jour de l'année précédente
            "YTD",
                DATE ( YEAR ( MAX ( 'Calendar'[Date] ) ) - 1, MONTH ( MAX ( 'Calendar'[Date] ) ), DAY ( MAX ( 'Calendar'[Date] ) ) ),
            [Current Period Start Date] - 1
        ),
    "Same Period Last Year",
        DATE ( YEAR ( MAX ( 'Calendar'[Date] ) ) - 1, MONTH ( MAX ( 'Calendar'[Date] ) ), DAY ( MAX ( 'Calendar'[Date] ) ) ),
    "Vague 1", DATE ( 2024, 4, 30 ),
    BLANK ()
)

`3.2.` La période principale

Ça c’est le plus simple, comme notre table Date Period utilise des formules de time intelligence, il n’y a plus qu’à gérer le cas où l’utilisateur choisit Custom.

Exemple pour une métrique, nouveaux utilisateurs :

sql
Current New Users =
SWITCH (
    TRUE (),
    SELECTEDVALUE ( 'Date Period'[Type] ) = "Custom", SUM ( TableDeMetriques[total_new_users] ),
    CALCULATE (
        SUM ( TableDeMetriques[total_new_users] ),
        REMOVEFILTERS ( 'Calendar'[Date] )
    )
)

REMOVEFILTERS ( 'Calendar'[Date] ) est indispensable pour la même raison que pour la mesure Current Period Start Date

`3.3.` La période de comparaison

Pour la période de comparaison, il y a plus d’étapes parce que la sélection du type de comparaison (Previous Period, Same Period Last Year, ou Custom) n’ont pas de fonction de time intelligence derrière. De plus, on a besoin d’un peu plus d’adaptabilité car lorsque la période principale est MTD et la période de comparaison est Previous Period, nous voulons que la comparaison donne le Previous MTD (e.g. Période principale : 01/08 - 13/08 alors Période de comparaison : 01/07 - 13/07 - et pas 19/07 - 31/07). La même logique applique pour Last Month où on ne veut pas avoir en comparaison les 30 jours d’avant (si le mois dernier est septembre), mais le mois précédent en entier (donc août). En résumé, on veut comparer des période équivalentes.

Pour rendre les choses plus compréhensibles, on va séparer notre mesure en 3 :

Comparaison Custom

sql
Custom Comparison Period New Users =
CALCULATE (
    SUM ( TableDeMetriques[total_new_users] ),
    USERELATIONSHIP ( 'Calendar Comparison'[Date], TableDeMetriques[measured_at] ),
    ALL ( 'Calendar' )
)

USERELATIONSHIP() est indispensable ici pour que notre relation inactive () soit rendue active pour cette mesure

ALL ( 'Calendar' ) est là pour spécifier que l’on souhaite enlever tous les filtres appliqués à la table Calendar dans cette mesure

Comparaison Previous Period

sql
Previous Period New Users =
VAR PeriodType =
    SELECTEDVALUE ( 'Date Period'[Type] )
VAR CurrentDate =
    MAX ( 'Calendar'[Date] )
VAR LastMonthDate =
    DATE ( YEAR ( CurrentDate ), MONTH ( CurrentDate ) - 1, DAY ( CurrentDate ) )
VAR CurrentQuarter =
    QUARTER ( CurrentDate )
VAR CurrentYear =
    YEAR ( CurrentDate )
VAR CurrentQuarterStartDate =
    DATE ( CurrentYear, ( CurrentQuarter - 1 ) * 3 + 1, 1 )
VAR LastQuarter =
    IF ( CurrentQuarter = 1, 4, CurrentQuarter - 1 )
VAR LastQuarterYear =
    IF ( CurrentQuarter = 1, CurrentYear - 1, CurrentYear )
VAR LastQuarterStartDate =
    DATE ( LastQuarterYear, ( LastQuarter - 1 ) * 3 + 1, 1 )
VAR DaysIntoQuarter =
    DATEDIFF ( CurrentQuarterStartDate, CurrentDate, DAY )
VAR LastQuarterEndDate = LastQuarterStartDate + DaysIntoQuarter - 1
VAR LastYear = CurrentYear - 1
VAR LastYearStartDate =
    DATE ( LastYear, 1, 1 )
VAR LastYearEndDate =
    DATE ( LastYear, MONTH ( CurrentDate ), DAY ( CurrentDate ) )
RETURN
    SWITCH (
        TRUE (),
        // Cas MTD : Calculer Previous MTD
        PeriodType = "MTD",
            CALCULATE (
                SUM ( 'TableDeMetriques'[total_new_users] ),
                'Calendar'[Date] <= LastMonthDate
                    && MONTH ( 'Calendar'[Date] ) = MONTH ( LastMonthDate )
                    && YEAR ( 'Calendar'[Date] ) = YEAR ( LastMonthDate ),
                REMOVEFILTERS ( 'Date Period'[Type] )
            ),
        // Cas QTD : Calculer Previous QTD
        PeriodType = "QTD",
            CALCULATE (
                SUM ( 'TableDeMetriques'[total_new_users] ),
                'Calendar'[Date] >= LastQuarterStartDate
                    && 'Calendar'[Date] <= LastQuarterEndDate
                    && QUARTER ( 'Calendar'[Date] ) = LastQuarter
                    && YEAR ( 'Calendar'[Date] ) = LastQuarterYear,
                REMOVEFILTERS ( 'Date Period'[Type] )
            ),
        // Cas YTD : Calculer Previous YTD
        PeriodType = "YTD",
            CALCULATE (
                SUM ( 'TableDeMetriques'[total_new_users] ),
                'Calendar'[Date] >= LastYearStartDate
                    && 'Calendar'[Date] <= LastYearEndDate
                    && YEAR ( 'Calendar'[Date] ) = LastYear,
                REMOVEFILTERS ( 'Date Period'[Type] )
            ),
        // Cas Last Month : Calculer le mois complet précédent
        PeriodType = "Last Month",
            CALCULATE (
                SUM ( 'TableDeMetriques'[total_new_users] ),
                PARALLELPERIOD ( 'Calendar'[Date], -1, MONTH ),
                REMOVEFILTERS ( 'Date Period'[Type] )
            ),
        // Cas Last Quarter : Calculer le trimestre complet précédent
        PeriodType = "Last Quarter",
            CALCULATE (
                SUM ( 'TableDeMetriques'[total_new_users] ),
                PARALLELPERIOD ( 'Calendar'[Date], -1, QUARTER ),
                REMOVEFILTERS ( 'Date Period'[Type] )
            ),
        // Cas Last Year : Calculer l'année complète précédente
        PeriodType = "Last Year",
            CALCULATE (
                SUM ( 'TableDeMetriques'[total_new_users] ),
                PARALLELPERIOD ( 'Calendar'[Date], -1, YEAR ),
                REMOVEFILTERS ( 'Date Period'[Type] )
            ),
        // Cas par défaut : Utiliser Previous Period Start Date et End Date si pas de sélection spéciale
        CALCULATE (
            SUM ( 'TableDeMetriques'[total_new_users] ),
            DATESBETWEEN (
                'Calendar'[Date],
                [Current Period Start Date] - [Current Period Number Of Days],
                [Current Period Start Date] - 1
            ),
            REMOVEFILTERS ( 'Date Period'[Type] )
        )
    )

Les variables servent à définir des dates pour pouvoir calculer les périodes précédentes pour MTD, QTD, et YTD

Pour Last Month, Last Quarter, et Last Year, on utilise la fonction PARALLELPERIOD()

On regroupe tout ça dans une seule mesure

Pour rendre la logique plus simple on a séparer la mesure de comparaison en plusieurs (il y a seulement pour l’option Same Period Last Year que j’ai opté pour rédiger la logique directement dans la mesure de regroupement, mais vous pouvez opter pour la séparer

sql
Full Comparison Period New Users =
SWITCH (
    SELECTEDVALUE ( 'Date Period Comparison'[comparison period] ),
    "Custom", [Custom Comparison Period New Users],
    // Période personnalisée, utilise la logique de comparaison personnalisée
    "Previous Period", [Previous Period New Users],
    // Utilise la mesure de période précédente sans autres slicers
    "Same Period Last Year",
        CALCULATE (
            SUM ( 'TableDeMetriques'[total_new_users] ),
            SAMEPERIODLASTYEAR ( 'Calendar'[Date] ),
            REMOVEFILTERS ( 'Date Period'[Type] ) // Ignore le filtre sur la comparaison de période
        ),
    "Vague 1",
        CALCULATE (
            SUM ( 'TableDeMetriques'[total_new_users] ),
            DATESBETWEEN ( 'Calendar'[Date], DATE ( 2024, 4, 4 ), DATE ( 2024, 4, 30 ) ),
            REMOVEFILTERS ( 'Date Period'[Type] )
        ),
    BLANK ()
)

SAMEPERIODLASTYEAR() permet de calculer tous les cas pour l’option de comparaison Same Period Last Year sauf pour les comparaisons statiques comme Vague 1 qui doit donc être traité séparément

On a tout ce qu’il nous faut ! 💃

Maintenant on peut utiliser dans nos visuels les mesures Current New Users et Full Comparison Period New Users

`3.4.` [Bonus] Les % de différence

Et pour les courageux qui ont tenu jusqu’ici, ce qui est bien pratique avec ces mesures c’est que l’on peut les utiliser facilement pour calculer des pourcentages de différence :

sql
% Diff New Users =
CONCATENATE (
    CONCATENATE (
        IF ( [Current New Users] >= [Full Comparison Period New Users], "+", "" ),
        ROUND (
            (
                DIVIDE (
                    [Current New Users] - [Full Comparison Period New Users],
                    [Full Comparison Period New Users],
                    0
                )
            ) * 100,
            1
        )
    ),
    "%"
)

PS : Je vous ai même inclus la méthode pour avoir directement le format +X% ou -X%

✍️

L’auteure : Eva Despesse

BI Engineer chez UnNest, Eva est en charge des sujets de modélisation de la donnée et du dashboarding, notamment sur Tableau et Power BI.

Ayant commencé dans une start-up, j’ai pu toucher aux flux de données de bout en bout. J’apprécie particulièrement faire les modélisations en bout de chaine avec le dashboarding pour suivre toute la chaine de transformation de données en information.

✉️ Me contacter : eva.despesse@unnest.co

↗️ Me suivre sur LinkedIn

Power BI : Créer des Filtres de Date Intelligents avec Comparaisons Customisées et Pré-Configurées

1. Les tables à créer

1.1. La création des tables

A. Les calendriers

B. Les périodes

1.2. Les relations entre les tables

A. Calendar <> Table de métriques

B. Calendar Comparison <> Table de métriques

C. Calendar <> Date Period

D. Modèle global

2. La mise en place des slicers

2.1. Les éléments

2.2. Les mesures de filtre

2.3. Les interactions entre les visuels

3. Les mesures

3.1. Les dates de début et de fin de période

3.2. La période principale

3.3. La période de comparaison

3.4. [Bonus] Les % de différence